package C4::Boolean;

#package to handle Boolean values in the parameters table

# Note: This is just a utility module; it should not be instantiated.

# Copyright 2003 Katipo Communications

#

# This file is part of Koha.

#

# Koha is free software; you can redistribute it and/or modify it

# under the terms of the GNU General Public License as published by

# the Free Software Foundation; either version 3 of the License, or

# (at your option) any later version.

#

# Koha is distributed in the hope that it will be useful, but

# WITHOUT ANY WARRANTY; without even the implied warranty of

# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the

# GNU General Public License for more details.

#

# You should have received a copy of the GNU General Public License

# along with Koha; if not, see <http://www.gnu.org/licenses>.

use strict;

use warnings;

use Carp;

use base qw(Exporter);

our    @EXPORT_OK = qw( true_p);

=head1 NAME

C4::Boolean - Convenience function to handle boolean values

in the parameter table

=head1 SYNOPSIS

  use C4::Boolean;

=head1 DESCRIPTION

In the parameter table, there are various Boolean values that

variously require a 0/1, no/yes, false/true, or off/on values.

This module aims to provide scripts a means to interpret these

Boolean values in a consistent way which makes common sense.

=head1 FUNCTIONS

=over 2

=cut

use constant INVALID_BOOLEAN_STRING_EXCEPTION =>

  q{The given value does not seem to be interpretable as a Boolean value};

our %strings = (

   '0'     => 0,    '1'     => 1,    # C

                    '-1'    => 1,    # BASIC

   'nil'   => 0,    't'     => 1,    # LISP

   'false' => 0,    'true'  => 1,    # Pascal

   'off'   => 0,    'on'    => 1,

   'no'    => 0,    'yes'   => 1,

   'n'     => 0,    'y'     => 1,

);

=item true_p

    if ( C4::Boolean::true_p(C4::Context->preference("IndependentBranches")) ) {

    ...

    }

Tries to interpret the passed string as a Boolean value. Returns

the value if the string can be interpreted as such; otherwise an

exception is thrown.

=cut

sub true_p  {

    my $x = shift;

    my $it;

    if (!defined $x || ref $x ) {

        carp INVALID_BOOLEAN_STRING_EXCEPTION;

        return;

    }

    $x = lc $x;

    $x =~ s/\s//g;

    if (defined $strings{$x}) {

        $it = $strings{$x};

    } else {

        carp INVALID_BOOLEAN_STRING_EXCEPTION;

    }

    return $it;

}

1;

__END__

=back

=head1 AUTHOR

Koha Development Team <http://koha-community.org/>

=cut

use C4::Boolean;

sub boolean_preference {

    my $self = shift;

    my $var = shift;        # The system preference to return

    my $it = preference($self, $var);

    return defined($it)? C4::Boolean::true_p($it): undef;

}

use C4::Boolean;

use C4::Boolean;

sub _normalize_value {

    my ($row) = @_;

    # AFAIK, there are no sysprefs where NULL has a different meaning than ''.

    return ( $row->{'value'} || '' ) unless ( $row->{'type'} eq 'YesNo' );

    #

    # In theory, YesNo sysprefs should always contain 1/0.

    # In practice, however, they don't.

    # - Yogi Berra

    #

    my $bool_value = eval {

        return C4::Boolean::true_p( $row->{'value'} ) ? 1 : 0;

    };

    if ( $@ ) {

        return 0;

    } else {

        return $bool_value;

    }

}

    foreach my $row ( @$current_state ) {

        # YAML::Syck encodes no as '', so deal with that

        $preferences{$row->{'variable'}} = $preferences{$row->{'variable'}} eq '' ? 0 : C4::Boolean::true_p( $preferences{$row->{'variable'}} ) if ( $row->{'type'} eq 'YesNo' );

    }

use Modern::Perl;

use Test::More tests => 22;

use Test::Warn;

BEGIN { use_ok( 'C4::Boolean', qw( true_p ) ); }

is( true_p('0'),     '0', 'recognizes \'0\' as false' );

is( true_p('nil'),   '0', 'recognizes \'nil\' as false' );

is( true_p('false'), '0', 'recognizes \'false\' as false' );

is( true_p('off'),   '0', 'recognizes \'off\' as false' );

is( true_p('no'),    '0', 'recognizes \'no\' as false' );

is( true_p('n'),     '0', 'recognizes \'n\' as false' );

is( true_p('NO'),    '0', 'verified case insensitivity' );

is( true_p('1'),    '1', 'recognizes \'1\' as true' );

is( true_p('-1'),   '1', 'recognizes \'-1\' as true' );

is( true_p('t'),    '1', 'recognizes \'t\' as true' );

is( true_p('true'), '1', 'recognizes \'true\' as true' );

is( true_p('on'),   '1', 'recognizes \'on\' as true' );

is( true_p('yes'),  '1', 'recognizes \'yes\' as true' );

is( true_p('y'),    '1', 'recognizes \'y\' as true' );

is( true_p('YES'),  '1', 'verified case insensitivity' );

my $result;

warning_like { $result = true_p(undef) }

             qr/^The given value does not seem to be interpretable as a Boolean value/,

             'Invalid boolean (undef) raises warning';

is( $result, undef, 'recognizes undefined as not boolean' );

warning_like { $result = true_p('foo') }

             qr/^The given value does not seem to be interpretable as a Boolean value/,

             'Invalid boolean (\'foo\') raises warning';

is( $result, undef, 'recognizes \'foo\' as not boolean' );

warning_like { $result = true_p([]) }

             qr/^The given value does not seem to be interpretable as a Boolean value/,

             'Invalid boolean (reference) raises warning';

is( $result, undef, 'recognizes a reference as not a boolean' );

-