- 

#!/usr/bin/perl

use Modern::Perl;

use sigtrap qw/die normal-signals/;

use Cwd qw(realpath);

use File::Basename;

use File::Find;

use File::Spec;

use FindBin;

use Test::More;

my $root = realpath("$FindBin::RealBin/..");

my @filepaths;

sub wanted {

    my $filepath = $File::Find::name;

    if ($filepath =~ /\.(pm|pl)$/) {

        push @filepaths, $filepath;

    }

}

find( { wanted => \&wanted, no_chdir => 1 }, $root );

plan tests => scalar @filepaths;

foreach my $filepath (@filepaths) {

    my $rel_path = File::Spec->abs2rel($filepath, $root);

    my $cmd = sprintf('perl -c "%s" 2>&1', $filepath);

    # FIXME It's the only file that requires a specific @INC

    # We should move misc/translator/*.pm to Koha namespace

    if ($rel_path eq 'misc/translator/TmplTokenizer.pm') {

        my $inc = dirname($filepath);

        $cmd = sprintf('perl -I "%s" -c "%s" 2>&1', $inc, $filepath);

    }

    my $output = `$cmd`;

    like($output, qr/syntax OK/, $rel_path);

}