=head3 extended_attributes

REST API embed of additional_field_values

=cut

sub extended_attributes {

    my ($self, $extended_attributes) = @_;

    if ($extended_attributes) {

        $self->set_additional_fields($extended_attributes);

    }

    my $afv_rs = $self->_result->extended_attributes;

    return Koha::AdditionalFieldValues->_new_from_dbic($afv_rs);

}

=head3 strings_map

Returns a map of column name to string representations including the string,

the mapping type and the mapping category where appropriate.

Currently handles additional fields values mappings.

Accepts a param hashref where the 'public' key denotes whether we want the public

or staff client strings.

=cut

sub strings_map {

    my ( $self, $params ) = @_;

    my $afvs    = $self->get_additional_field_values_for_template;

    my $strings = {};

    foreach my $af_id ( keys %{$afvs} ) {

        my $additional_field = Koha::AdditionalFields->find($af_id);

        my $av_cat           = $additional_field->effective_authorised_value_category;

        my @af_value_arr;

        my $af_value_str;

        my $value_to_push;

        foreach my $av_value ( @{ $afvs->{$af_id} } ) {

            if ($av_cat) {

                my $av = Koha::AuthorisedValues->search(

                    {

                        category         => $av_cat,

                        authorised_value => $av_value,

                    }

                );

                $value_to_push =

                    $av->count ? $params->{public} ? $av->next->opac_description : $av->next->lib : $av_value;

            } else {

                $value_to_push = $av_value;

            }

            push @af_value_arr, $value_to_push if $value_to_push;

        }

        $af_value_str = join( ", ", @af_value_arr );

        push(

            @{ $strings->{additional_field_values} },

            {

                field_label => $additional_field->name,

                value_str   => $af_value_str,

                type        => $av_cat ? 'av' : 'text',

                field_id    => $af_id,

            }

        );

    }

    my @sorted = sort { $a->{field_id} <=> $b->{field_id} } @{ $strings->{additional_field_values} };

    my @non_empty = grep { $_->{value_str} ne "" } @sorted;

    $strings->{additional_field_values} = \@non_empty;

    return $strings;

}