- 

#!/usr/bin/env perl

# This file is part of Koha.

#

# Koha is free software; you can redistribute it and/or modify it

# under the terms of the GNU General Public License as published by

# the Free Software Foundation; either version 3 of the License, or

# (at your option) any later version.

#

# Koha is distributed in the hope that it will be useful, but

# WITHOUT ANY WARRANTY; without even the implied warranty of

# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the

# GNU General Public License for more details.

#

# You should have received a copy of the GNU General Public License

# along with Koha; if not, see <http://www.gnu.org/licenses>.

use Modern::Perl;

use Test::More tests => 22;

use Test::MockModule;

use Test::Mojo;

use t::lib::Mocks;

use t::lib::TestBuilder;

use DateTime;

use C4::Context;

use C4::Circulation qw( AddIssue AddReturn CanBookBeIssued );

use Koha::Database;

use Koha::DateUtils qw( dt_from_string output_pref );

use Koha::Token;

my $schema  = Koha::Database->schema;

my $builder = t::lib::TestBuilder->new;

t::lib::Mocks::mock_preference( 'RESTBasicAuth', 1 );

my $t = Test::Mojo->new('Koha::REST::V1');

$schema->storage->txn_begin;

my $dbh = C4::Context->dbh;

my $branchcode = $builder->build( { source => 'Branch' } )->{branchcode};

my $librarian  = $builder->build_object(

    {

        class => 'Koha::Patrons',

        value => { flags => 2, branchcode => $branchcode }

    }

);

my $password = 'thePassword123';

$librarian->set_password( { password => $password, skip_validation => 1 } );

my $userid = $librarian->userid;

my $other_branchcode = $builder->build( { source => 'Branch' } )->{branchcode};

my $patron           = $builder->build_object(

    {

        class => 'Koha::Patrons',

        value => { flags => 0, branchcode => $other_branchcode },

    }

);

my $unauth_password = 'thePassword000';

$patron->set_password(

    { password => $unauth_password, skip_validattion => 1 } );

my $unauth_userid = $patron->userid;

my $patron_id     = $patron->borrowernumber;

my $item1    = $builder->build_sample_item;

my $item1_id = $item1->id;

my $itemtype = $builder->build( { source => 'Itemtype' } )->{itemtype};

my $biblio_2 = $builder->build_sample_biblio;

my $item_2   = $builder->build_sample_item(

    { biblionumber => $biblio_2->biblionumber, itype => $itemtype } );

my $item_2_barcode = $item_2->barcode;

my $item_2_id      = $item_2->id;

my $not_issued_item         = $builder->build_sample_item;

my $not_issued_item_id      = $not_issued_item->id;

my $not_issued_item_barcode = $not_issued_item->barcode;

my $barcode        = '321321321321';

my $matching_items = Koha::Items->search( { barcode => $barcode } );

while ( my $item = $matching_items->next ) {

    $item->delete;

}

my $non_existent_item         = $builder->build_sample_item;

my $non_existent_item_id      = $non_existent_item->id;

my $non_existent_item_barcode = $non_existent_item->barcode;

$non_existent_item->delete;

my $checkout = $builder->build_object(

    {

        class => 'Koha::Checkouts',

        value => {

            itemnumber     => $item1_id,

            branchcode     => $branchcode,

            borrowernumber => $patron_id,

            note           => undef,

            notedate       => undef,

            noteseen       => undef

        }

    }

);

my $checkout_id = $checkout->id;

my $reserved_checkout = $builder->build_object(

    {

        class => 'Koha::Checkouts',

        value => {

            itemnumber     => $item_2_id,

            branchcode     => $branchcode,

            borrowernumber => $patron_id,

            note           => undef,

            notedate       => undef,

            noteseen       => undef

        }

    }

);

my $reserved_checkout_id = $reserved_checkout->id;

$dbh->do('DELETE FROM reserves');

Koha::CirculationRules->search()->delete();

Koha::CirculationRules->set_rules(

    {

        categorycode => undef,

        branchcode   => undef,

        itemtype     => undef,

        rules        => {

            reservesallowed  => 1,

            holds_per_record => 99

        }

    }

);

my $reserve_id = C4::Reserves::AddReserve(

    {

        branchcode     => $branchcode,

        borrowernumber => $patron->borrowernumber,

        biblionumber   => $biblio_2->biblionumber,

        priority       => 1,

        itemnumber     => $item_2->itemnumber,

    }

);

# empty checkin

$t->post_ok( "//$userid:$password@/api/v1/checkin" => json => {} )

  ->status_is(400);

# checkin on unknow item id

$t->post_ok( "//$userid:$password@/api/v1/checkin" => json =>

      { item_id => $non_existent_item_id } )->status_is(404)

  ->json_is( { error => 'Item not found', error_code => 'ITEM_NOT_FOUND' } );

# checkin with unknow barcode

$t->post_ok( "//$userid:$password@/api/v1/checkin" => json =>

      { external_id => $non_existent_item_barcode } )->status_is(404)

  ->json_is( { error => 'Item not found', error_code => 'ITEM_NOT_FOUND' } );

# not isued

$t->post_ok( "//$userid:$password@/api/v1/checkin" => json =>

      { item_id => $not_issued_item_id, library_id => $branchcode } )

  ->status_is(403)->json_is( '/returned' => 0 )

  ->json_has( '/messages' => { NotIssued => $not_issued_item_barcode } );

# checkin okay

$t->post_ok( "//$userid:$password@/api/v1/checkin" => json =>

      { item_id => $item1_id, library_id => $branchcode } )->status_is(201)

  ->json_is( '/returned' => 1 )

  ->json_has(

    '/messages' => { TransferTrigger => 'ReturnToHome', WasReturned => '1' } );

#mismatch of item_id and barcode when both given

$t->post_ok(

    "//$userid:$password@/api/v1/checkin" => json => {

        item_id     => $not_issued_item_id,

        external_id => $item_2_barcode,

        library_id  => $branchcode

    }

)->status_is(409);

# reserved item

$t->post_ok( "//$userid:$password@/api/v1/checkin" => json =>

      { item_id => $item_2_id, library_id => $branchcode } )->status_is(201)

  ->json_is( '/returned' => 1 )->json_has(

    '/messages' => { WasReturned => '1' },

    '/ResFound' => { "ResFound"  => "Reserved" }

  );

$schema->storage->txn_rollback;