package C4::Utils::DataTables::ColumnsSettings;

use Modern::Perl;

use List::Util qw( first );

use YAML;

use C4::Context;

use Koha::Database;

sub get_yaml {

    my $yml_path =

      C4::Context->config('intranetdir') . '/admin/columns_settings.yml';

    my $yaml = eval { YAML::LoadFile($yml_path) };

    warn

"ERROR: the yaml file for DT::ColumnsSettings is not correctly formated: $@"

      if $@;

    return $yaml;

}

sub get_columns {

    my ( $module, $page, $tablename ) = @_;

    my $list = get_yaml;

    my $schema = Koha::Database->new->schema;

    my $rs = $schema->resultset('ColumnsSetting')->search(

        {

            module    => $module,

            page      => $page,

            tablename => $tablename,

        }

    );

    while ( my $c = $rs->next ) {

        my $column = first { $c->columnname eq $_->{columnname} }

        @{ $list->{modules}{ $c->module }{ $c->page }{ $c->tablename } };

        $column->{is_hidden}         = $c->is_hidden;

        $column->{cannot_be_toggled} = $c->cannot_be_toggled;

    }

    return $list->{modules}{$module}{$page}{$tablename} || [];

}

sub get_modules {

    my $list = get_yaml;

    my $schema = Koha::Database->new->schema;

    my $rs     = $schema->resultset('ColumnsSetting')->search;

    while ( my $c = $rs->next ) {

        my $column = first { $c->columnname eq $_->{columnname} }

        @{ $list->{modules}{ $c->module }{ $c->page }{ $c->tablename } };

        $column->{is_hidden}         = $c->is_hidden;

        $column->{cannot_be_toggled} = $c->cannot_be_toggled;

    }

    return $list->{modules};

}

sub update_columns {

    my ($params) = @_;

    my $columns = $params->{columns};

    my $schema = Koha::Database->new->schema;

    for my $c (@$columns) {

        $c->{is_hidden}         //= 0;

        $c->{cannot_be_toggled} //= 0;

        my $column = $schema->resultset('ColumnsSetting')->search(

            {

                module     => $c->{module},

                page       => $c->{page},

                tablename  => $c->{tablename},

                columnname => $c->{columnname},

            }

        );

        if ( $column->count ) {

            $column = $column->first;

            $column->update(

                {

                    module            => $c->{module},

                    page              => $c->{page},

                    tablename         => $c->{tablename},

                    columnname        => $c->{columnname},

                    is_hidden         => $c->{is_hidden},

                    cannot_be_toggled => $c->{cannot_be_toggled},

                }

            );

        }

        else {

            $schema->resultset('ColumnsSetting')->create(

                {

                    module            => $c->{module},

                    page              => $c->{page},

                    tablename         => $c->{tablename},

                    columnname        => $c->{columnname},

                    is_hidden         => $c->{is_hidden},

                    cannot_be_toggled => $c->{cannot_be_toggled},

                }

            );

        }

    }

}

1;

package Koha::Template::Plugin::ColumnsSettings;

# This file is part of Koha.

#

# Copyright BibLibre 2014

#

# Koha is free software; you can redistribute it and/or modify it

# under the terms of the GNU General Public License as published by

# the Free Software Foundation; either version 3 of the License, or

# (at your option) any later version.

#

# Koha is distributed in the hope that it will be useful, but

# WITHOUT ANY WARRANTY; without even the implied warranty of

# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the

# GNU General Public License for more details.

#

# You should have received a copy of the GNU General Public License

# along with Koha; if not, see <http://www.gnu.org/licenses>.

use Modern::Perl;

use Template::Plugin;

use base qw( Template::Plugin );

use YAML qw( LoadFile );

use JSON qw( to_json );

use C4::Context qw( config );

use C4::Utils::DataTables::ColumnsSettings;

=pod

This plugin allows to get the column configuration for a table.

First, include the line '[% USE Tables %]' at the top

of the template to enable the plugin.

To use, call ColumnsSettings.GetColumns with the module, the page and the table where the template is called.

For example: [% ColumnsSettings.GetColumns( 'circ', 'circulation', 'holdst' ) %]

=cut

sub GetColumns {

    my ( $self, $module, $page, $table, $format ) = @_;

    $format //= q{};

    my $columns = C4::Utils::DataTables::ColumnsSettings::get_columns( $module, $page, $table );

    return $format eq 'json'

        ? to_json( $columns )

        : $columns

}

1;

#!/usr/bin/perl

use Modern::Perl;

use CGI;

use YAML qw( LoadFile );

use C4::Auth;

use C4::Context;

use C4::Output;

use C4::Utils::DataTables::ColumnsSettings qw( get_modules );

my $input = new CGI;

my ( $template, $loggedinuser, $cookie ) = get_template_and_user(

    {

        template_name   => "admin/columns_settings.tt",

        query           => $input,

        type            => "intranet",

        authnotrequired => 0,

        flagsrequired   => { parameters => 'parameters_remaining_permissions' },

        debug           => 1,

    }

);

my $action = $input->param('action') // 'list';

if ( $action eq 'save' ) {

    my $module = $input->param('module');

    my @columnids = $input->param("columnid");

    my @columns;

    for my $columnid (@columnids) {

        next unless $columnid =~ m|^([^_]*)_([^_]*)_(.*)$|;

        my $is_hidden = $input->param( $columnid . '_hidden' ) // 0;

        my $cannot_be_toggled =

          $input->param( $columnid . '_cannot_be_toggled' ) // 0;

        push @columns,

          {

            module            => $module,

            page              => $1,

            tablename         => $2,

            columnname        => $3,

            is_hidden         => $is_hidden,

            cannot_be_toggled => $cannot_be_toggled,

          };

    }

    C4::Utils::DataTables::ColumnsSettings::update_columns(

        {

            columns => \@columns,

        }

    );

    $action = 'list';

}

if ( $action eq 'list' ) {

    my $modules = C4::Utils::DataTables::ColumnsSettings::get_modules;

    $template->param(

        panel   => ( $input->param('panel') || 0 ),

        modules => $modules,

    );

}

output_html_with_http_headers $input, $cookie, $template->output;

modules:

  module_name:

    page_name:

      table_id:

        -

          columnname: my_column_name

        -

          columnname: my_other_column_name

          cannot_be_toggled: 1

          cannot_be_modified: 1

    <li><a href="/cgi-bin/koha/admin/columns_settings.pl">Columns settings</a></li>

[% USE ColumnsSettings %]

<script type="text/javascript">

function KohaTable(selector, dt_parameters, columns_settings) {

    var id = 0;

    var hidden_ids = [];

    var excluded_ids = [];

    $(columns_settings).each( function() {

        if ( this['is_hidden'] == "1" ) {

            hidden_ids.push( id );

        }

        if ( this['cannot_be_toggled'] == "1" ) {

            excluded_ids.push( id );

        }

        id++;

    });

    dt_parameters[ "oColVis" ] = { "aiExclude": excluded_ids };

    var table = $(selector).dataTable($.extend(true, {}, dataTablesDefaults, dt_parameters));

    $(hidden_ids).each(function(index, value) {

        table.fnSetColumnVis( value, false );

    });

    return table;

}

</script>

    <dt><a href="/cgi-bin/koha/admin/columns_settings.pl">Configure columns</a></dt>

    <dd>Hide or show columns for tables.</dd>