use File::Slurp;

use constant ATOMICUPD_PREF => '_LocalAtomicUpdates';

my $aupd = { #hash for atomic updates

    location  => C4::Context->config('intranetdir')."/installer/data/mysql/atomicupdate",

    remember  => C4::Context->preference(ATOMICUPD_PREF)//'',

    skipfiles => {

        'Bug-4246-Talking-Tech-itiva-phone-notifications.pl' => 1,

        'oai_sets.sql' => 1,

    },

};

#FIXME Will be fixed with the first db rev new style

#The first dbrev should look like this:

#ExecDBRev( $aupd, '13068', 'Refined dbrev', '13068.pl', '3.17.00.032');

# This point marks the end of the approved database revisions.

# The following line runs proposed patches found in atomicupdate. On a

# production system, it will [should] not find any.

RunRemainingAtomicUpdates( $aupd );

=head2 RunRemainingAtomicUpdates

This subroutine will run all development updates in the atomicupdate

directory. It will skip the official db revisions, that have been

collected in the skipfiles hash. It also skips recently applied

dev updates as recorded in local pref _LocalAtomicUpdates.

=cut

sub RunRemainingAtomicUpdates {

    my ( $atomicupd ) = @_;

    my $loc = $atomicupd->{location};

    my @updates = glob( $loc .'/*');

    foreach my $upd ( sort @updates ) { #sort feels safer here

        $upd =~ s/$loc\///;

        if( exists $atomicupd->{skipfiles}->{$upd} ) {

        #Skip files that belong to official db revisions

           print "Skipping $upd as installed official db rev\n";

           next;

        }

        if( $atomicupd->{remember} =~ /(^|;)$upd;/ ) {

        #Skip files that have recently been applied

        #Note that an official db rev erases this list

           print "Skipping $upd as recently applied dev update\n";

           next;

        }

        if( $upd !~ /\.(txt|sql|pl)$/ ) {

            print "Unsupported file format: $upd\n";

            next;

        }

        ExecDBRev( $atomicupd, '', '', $upd, 'XXX' );

   }

}

=head2 ExecDBRev

This subroutine checks if an official db revision should still be

applied. If not, it records the file in the skipfiles hash and returns.

Otherwise it applies the db rev from the atomicupdate directory.

The db rev can be a perl file, a sql file or a txt file.

=cut

sub ExecDBRev {

    my ( $atomicupd, $bugno, $descr, $file, $version ) = @_;

    my $devrun = $version=~/XXX$/;

    $atomicupd->{skipfiles}->{$file} = 1 if !$devrun && $file;

    return 0 if !CheckVersion($version);

    my $rv;

    if( $file =~ /\.txt$/ ) {

    #This dbrev prints some warning

        my $contents= read_file( $atomicupd->{location}. "/$file" );

        print $contents;

        $rv = 1;

    } elsif( $file =~ /\.pl$/ ) {

    #Run perl script

        $rv = do $atomicupd->{location}. "/$file";

        if( !$rv ) {

            print "ERROR: $@\n" if $@;

            print "ERROR: $!\n" if $!;

            $rv = 1 if !$! && !$@; #apparently, the file does not end with 1;

        }

    } elsif( $file =~ /\.sql$/ ) {

    #Run sql file via installer

        my $installer = C4::Installer->new();

        $rv = $installer->load_sql( $atomicupd->{location}. "/$file" )? 0: 1;

        #Note: load_sql already warns

    } else {

        print "DB rev $version contains unsupported file $file\n";

        $rv = 0;

    }

    if( $devrun ) {

        print "Dev upgrade $file done\n";

        _atomic_memory( $atomicupd, $file ) if $rv;

    } else {

        _atomic_memory( $atomicupd ); #Official db rev clears the atomic pref

        SetVersion($version);

        print "Upgrade to $version done (Bug $bugno - $descr)\n";

    }

}

sub _atomic_memory {

    my ( $atomicupd, $upd ) = @_;

    $atomicupd->{remember}= $upd? $atomicupd->{remember}."$upd;": '';

    C4::Context->set_preference( ATOMICUPD_PREF, $atomicupd->{remember} );

}