sub sync_kohafield {

    my ( $class ) = @_;

    # Clear the destination frameworks first

    Koha::MarcSubfieldStructures->search({ frameworkcode => { '>', q{} }, kohafield => { '>', q{} } })->update({ kohafield => undef });

    # Now copy from Default

    my $rs = Koha::MarcSubfieldStructures->search({ frameworkcode => q{}, kohafield => { '>', q{} } });

    while( my $rec = $rs->next ) {

        Koha::MarcSubfieldStructures->search({ frameworkcode => { '>', q{} }, tagfield => $rec->tagfield, tagsubfield => $rec->tagsubfield })->update({ kohafield => $rec->kohafield });

    }

    # Clear the cache

    my @fw = Koha::BiblioFrameworks->search({ frameworkcode => { '>', q{} } })->get_column('frameworkcode');

    foreach( @fw ) {

        Koha::Caches->get_instance->clear_from_cache( "MarcSubfieldStructure-$_" );

    }

    Koha::Caches->get_instance->clear_from_cache("default_value_for_mod_marc-");

}

=head3 get_kohafield_exceptions

    Get all kohafield exceptions (deviations from the Default framework)

    Returns an arrayref of [ framework, field, subfield, kohafield ]

    where kohafield is the original (deviating) value.

=cut

sub get_kohafield_exceptions {

    my ( $class, $params ) = @_;

    # Too bad that DBIx is not very helpful here

    my $default = Koha::MarcSubfieldStructures->search({

        frameworkcode => q{},

        kohafield => { '>' => '' },

    });

    my $other = Koha::MarcSubfieldStructures->search({

        frameworkcode => { '!=' => q{} },

    }, { order_by => { -asc => [ qw/tagfield tagsubfield/ ] } });

    # Compare

    my @return;

    while( my $rec = $other->next ) {

        my @tags = ( $rec->tagfield, $rec->tagsubfield );

        my $defa = $default->find( q{}, @tags );

        if( $rec->kohafield ) {

            push @return, [ $rec->frameworkcode, @tags, $rec->kohafield ] if !$defa || !$defa->kohafield || $defa->kohafield ne $rec->kohafield;

        } else {

            push @return, [ $rec->frameworkcode, @tags, q{} ] if $defa && $defa->kohafield;

        }

    }

    return \@return;

}

$DBversion = 'XXX';  # will be replaced by the RM

if( CheckVersion( $DBversion ) ) {

    require Koha::MarcSubfieldStructures;

    my $diff = Koha::MarcSubfieldStructures->get_kohafield_exceptions;

    if( @$diff ) {

        print "WARNING: The Default framework is now considered as authoritative for Koha to MARC mappings. We have found that your additional frameworks contained ".@$diff." mapping(s) that deviate from the standard mappings. Please look at the following list and consider if you need to add them again in Default (possibly as a second mapping).\n";

        foreach( @$diff ) {

            print "Field ". $_->[1].$_->[2]. " in framework ". $_->[0]. ": ";

            if( $_->[3] ) {

                print "Mapping to ". $_->[3]. " has been adjusted.\n";

            } else {

                print "Mapping has been reset.\n";

            }

        }

        Koha::MarcSubfieldStructures->sync_kohafield;

    }

    SetVersion( $DBversion );

    print "Upgrade to $DBversion done (Bug 19096 - Make Default authoritative for Koha to MARC mappings)\n";

}

subtest 'get_kohafield_exceptions / sync_kohafield' => sub {

    plan tests => 14;

    # start from scratch again, add a new framework

    Koha::MarcSubfieldStructures->delete;

    my $builder = t::lib::TestBuilder->new;

    my $fwc = $builder->build({ source => 'BiblioFramework' })->{frameworkcode};

    # 100a mapped in Default, unmapped in other

    Koha::MarcSubfieldStructure->new({ frameworkcode => q{}, tagfield => '100', tagsubfield => 'a', kohafield => 'biblio.author' })->store;

    Koha::MarcSubfieldStructure->new({ frameworkcode => $fwc, tagfield => '100', tagsubfield => 'a', kohafield => '' })->store;

    my $res = Koha::MarcSubfieldStructures->get_kohafield_exceptions;

    is( @$res, 1, 'Found one exception' );

    is( $res->[0]->[1] . $res->[0]->[2], '100a', '100a was reported' );

    Koha::MarcSubfieldStructures->sync_kohafield;

    $res = Koha::MarcSubfieldStructures->get_kohafield_exceptions;

    is( @$res, 0, 'Found no exceptions after syncing' );

    is( Koha::MarcSubfieldStructures->find($fwc, '100', 'a')->kohafield,

        'biblio.author', '100a in added framework adjusted' );

    # 245a unmapped in Default, mapped in other

    # 300a not in Default, mapped in other

    Koha::MarcSubfieldStructure->new({ frameworkcode => q{}, tagfield => '245', tagsubfield => 'a', kohafield => q{} })->store;

    Koha::MarcSubfieldStructure->new({ frameworkcode => $fwc, tagfield => '245', tagsubfield => 'a', kohafield => 'biblio.title' })->store;

    Koha::MarcSubfieldStructure->new({ frameworkcode => $fwc, tagfield => '300', tagsubfield => 'a', kohafield => 'biblioitems.pages' })->store;

    $res = Koha::MarcSubfieldStructures->get_kohafield_exceptions;

    is( @$res, 2, 'Found two exceptions' );

    is( $res->[0]->[1] . $res->[0]->[2], '245a', '245a was reported' );

    is( $res->[1]->[1] . $res->[1]->[2], '300a', '300a was reported' );

    Koha::MarcSubfieldStructures->sync_kohafield;

    $res = Koha::MarcSubfieldStructures->get_kohafield_exceptions;

    is( @$res, 0, 'Found no exceptions after syncing again' );

    is( Koha::MarcSubfieldStructures->find($fwc, '245', 'a')->kohafield,

        undef, '245a in added framework cleared' );

    is( Koha::MarcSubfieldStructures->find($fwc, '300', 'a')->kohafield,

        undef, '300a in added framework cleared' );

    # 300a mapped in Default to another field than in other framework

    Koha::MarcSubfieldStructure->new({ frameworkcode => q{}, tagfield => '300', tagsubfield => 'a', kohafield => 'something_else' })->store;

    Koha::MarcSubfieldStructures->find($fwc, '300', 'a')->update({ kohafield => 'biblioitems.pages' });

    $res = Koha::MarcSubfieldStructures->get_kohafield_exceptions;

    is( @$res, 1, 'Found one exception' );

    is( $res->[0]->[1] . $res->[0]->[2], '300a', '300a was reported again' );

    Koha::MarcSubfieldStructures->sync_kohafield;

    $res = Koha::MarcSubfieldStructures->get_kohafield_exceptions;

    is( @$res, 0, 'Found no exceptions after third syncing' );

    is( Koha::MarcSubfieldStructures->find($fwc, '300', 'a')->kohafield,

        'something_else', '300a in added framework adjusted' );

};