package Koha::App::Koha;

use Modern::Perl;

use Mojo::Base 'Mojolicious';

sub startup {

    my ($self) = @_;

    push @{$self->plugins->namespaces}, 'Koha::App::Plugin';

    push @{$self->static->paths}, $self->home->rel_file('koha-tmpl');

    # Create route for all CGI scripts, need to be loaded first because of

    # CGI::Compile

    $self->plugin('CGIBinKoha');

    # Create routes for API

    # FIXME This generates routes like this: /api/api/v1/...

    $self->plugin('RESTV1');

    $self->hook(before_dispatch => \&_before_dispatch);

    # Everything after this comment is only needed to use Mojolicious

    # controllers.

    # We can't use them for anything serious right now because of the

    # authentication code that needs a full rewrite

    $self->plugin('TemplateToolkit', template => {PLUGIN_BASE => 'Koha::Template::Plugin'});

    $self->renderer->default_handler('tt2');

    $self->routes->namespaces(['Koha::Controller']);

    my $r = $self->routes;

    $r->any('/')->to(cb => sub { shift->redirect_to('/cgi-bin/koha/opac-main.pl') });

    $r->any('/intranet')->to(cb => sub { shift->redirect_to('/cgi-bin/koha/mainpage.pl') });

}

sub _before_dispatch {

    my $c = shift;

    # URL rewriting in Koha! No Apache/Nginx conf needed

    my $url = $c->req->url->path->to_string;

    # Remove Koha version from URL

    $url =~ s/_\d{2}\.\d{7}\.(js|css)/.$1/;

    # See FIXME above

    if ($url =~ m|^/api/v|) {

        $url = '/api' . $url;

    }

    $c->req->url->parse($url);

}

1;

package Koha::App::Plugin::CGIBinKoha;

use Modern::Perl;

use Mojo::Base 'Mojolicious::Plugin';

use CGI::Compile;

use CGI::Emulate::PSGI;

use IO::Scalar;

sub register {

    my ($self, $app) = @_;

    $app->routes->any('/cgi-bin/koha/*name' => sub {

        my ($c) = @_;

        my $script = $c->stash('name');

        # Special case for installer which can takes a long time

        $c->inactivity_timeout(300) if $script eq 'installer/install.pl';

        # Remove trailing slash, if any (e.g. .../svc/config/systempreferences/)

        $script =~ s|/$||;

        # Guess if it's an OPAC script, or an Intranet script

        # FIXME: errors scripts (400.pl, 401.pl, ...) exist in both intranet and

        # opac. The intranet ones will never be executed

        # Same for svc/club/cancel_enrollment, svc/club/enroll and svc/report

        if (-e $c->app->home->rel_file("opac/$script")) {

            $script = "opac/$script";

        }

        unless (-e $c->app->home->rel_file($script)) {

            return $c->reply->not_found;

        }

        my $sub = CGI::Compile->compile($script);

        my $app = CGI::Emulate::PSGI->handler($sub);

        my $response = $app->($self->_psgi_env($c));

        $c->res->code($response->[0]);

        $c->res->headers->from_hash({ @{ $response->[1] } });

        $c->res->body(join('', @{$response->[2]}));

        $c->rendered;

    })->name('cgi');

}

sub _psgi_env {

    my ($self, $c) = @_;

    my $body = $c->req->body;

    my $env = {

        'psgi.input' => IO::Scalar->new(\$body),

        'psgi.errors' => *STDERR,

        REQUEST_METHOD => $c->req->method,

        QUERY_STRING => $c->req->url->query->to_string,

        SERVER_NAME => $c->req->url->to_abs->host,

        SERVER_PORT => $c->req->url->to_abs->port,

        SERVER_PROTOCOL => 'HTTP/1.1',

        CONTENT_LENGTH => $c->req->headers->content_length,

        CONTENT_TYPE => $c->req->headers->content_type,

        REMOTE_ADDR => $c->tx->remote_address,

        SCRIPT_NAME => $c->req->url->path->to_string,

    };

    for my $name (@{ $c->req->headers->names }) {

        my $value = $c->req->headers->header($name);

        $name =~ s/-/_/g;

        $name = 'HTTP_' . uc($name);

        $env->{$name} = $value;

    }

    return $env;

}

1;

package Koha::App::Plugin::RESTV1;

use Modern::Perl;

use Mojo::Base 'Mojolicious::Plugin';

use Koha::REST::V1;

sub register {

    my ($self, $app) = @_;

    $app->routes->any('/api')->detour(app => Koha::REST::V1->new);

}

1;

#!/usr/bin/env perl

use Modern::Perl;

# No need for PERL5LIB

use FindBin;

use lib "$FindBin::Bin/..";

use Mojolicious::Commands;

Mojolicious::Commands->start_app('Koha::App::Koha');

#!/usr/bin/env starman

use Modern::Perl;

use FindBin;

use Mojo::Server::PSGI;

use Plack::Builder;

builder {

    my $server = Mojo::Server::PSGI->new;

    $server->load_app("$FindBin::Bin/koha");

    $server->to_psgi_app;

};